home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tiger Disk 53
/
Tiger_Disk_053_1998-08_Tiger-Crew-Disk_de_Side_B.d64
/
1581 id-changer
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
1KB
|
38 lines
5 poke53280,0:poke53281,1:print"[154]"
10 print "[147]change 1581 disk id#[146]"
20 print " disk unit nr (8-15) ?[160]8 [157][157][157][157]";
30 input u: if u<8 or u>15 then print "[145][145][145]": goto 20
40 print " disk drive nr (0/1) ?[160]0[157][157][157]";
50 input d: if d<0 or d>1 then print "[145][145][145]": goto 40
60 print " put target disk in unit";u;" drive";d
70 print " then press any key to continue"
80 get x$: if x$=""then 80
90 a=1: v=2 : q$=chr$(34): p$=chr$(160)
100 t=40: s=0: i$="i"+right$(str$(d),1)
110 open 1,u,15,i$: gosub 350
120 gosub 310: f$=h$: get#2,x$,x$,a$,b$
130 print"[147] current id# ";q$;f$;q$
150 print" new id# or quit[146] (q)[146] ?"
160 input " ?[157]";n$: l=len(n$):if l>v then130
170 if n$="q"thenprint"[147]";:goto370
180 print " ok to write new id# (y/n) ? y[157][157][157]";
190 input x$: if x$<>"y" then 130
200 if l=v then 220
210 for x=l+a to v: n$=n$+p$: next
220 print#1,"b-p:";2;22: print#2,n$;
230 print#1,"u2:";2;d;t;s: gosub 350
240 print#1,i$: gosub 350: close 2
250 print " old id# ";q$;f$;q$
260 gosub 310: close 2: close 1
270 print "new[146] id# ";q$;h$;q$
280 print " change another diskette (y/n) ? y[157][157][157]";
290 input x$: if x$="y" then 60
300 print "[147]";: end
310 open 2,u,2,"#": gosub 350: h$=""
320 print#1,"u1:";2;d;t;s: gosub 350
330 print#1,"b-p:";2;22: for x=atov
340 get#2,t$: h$=h$+t$: next: return
350 input#1,e,m$,j,k:if e=0 then return
360 print " error: ";e;m$;j;k
370 close 2: close 1: end